# =====================================================================
# SOURCE FILE NAME = startup.nsh
#
# EFI PCT startup file
# Initial release. Rev.# 0.4
# 
# =====================================================================

@echo -off
cls

for %d in fs0 fs1 fs2 fs3 fs4 fs5 fs6 fs7 fs8 fs9
    set -v drive %d
    echo Searching for %drive%:\pct\pct.bmp
    if exist %drive%:\pct\pct.bmp then
        echo Located pct.bmp in %drive%:\
        goto FOUNDMEDIA
    endif
endfor

:ERROR
 echo Unable to find PCT files.  
 echo Please check installation.
 echo ""
 pause
 goto END

:FOUNDMEDIA
cls
#echo "Press any key to continue..."
#loadbmp \pct\PCT.bmp -c -i1 -w0 > nul
cls
mode 80 25
cls
# =====================================================================
#  Area to add any warning messages or notes to display for cutomers
#  to view, also add any product specific issues in the area to display
#  to the customer.
# =====================================================================
echo "Release Notes:"
echo " - Release to support the S55xx resource CD."
echo ""
echo " - Please read the PCTread.txt file before running the test on the system.
echo "   
echo "   
echo ""
echo By downloading these confidence tests you agreed to adhere to a particular 
echo license agreement.  A copy of the agreement is included with this 
echo installation in the file legal.txt.
echo ""
echo By pressing any key other than q, you agree to be bound by this 
echo license agreement.
echo ""
stall 5000000 > nul
pause
cls
echo ""
echo ""
%drive%:
echo  Starting EFI PCT please wait..
echo "Loading ipmi.efi driver..."
load \efi\tools\ipmi.efi > nul
echo "Creating 128MB RAM Disk (FSZ:)..."
mkramdisk -d \pct\ramdisk.efi -s 128 FSZ > nul
echo "Copying PCT to RAM Disk"
cd \pct
cp * FSZ: > nul
echo "Copying EFI TOOLS to RAM Disk"
cd \efi\tools
cp * FSZ: > nul
echo "PCT install to RAM: Starting Test Menu..."
FSZ:
stall 2000000 > nul
cls
testmenu

:end
cls
