
echo off

  rem   ROCK'N ROLL Installation Batch Program, Copyright 1991 by Rainbow Arts
  rem   -----------------------------------------------------------------------
  rem   This batch is call by _INSTL.BAT to do the actual copying to two
  rem   360K - floppys. For larger disks and harddisk _copy.bat is used.
  rem   Parameters used:
  rem   %1 - source-drive
  rem   %2 - destination-drive
  rem   %3 - what to install: EGA or CGA
  rem   -----------------------------------------------------------------------

  rem   Check command line arguments
  rem   -----------------------------------------------------------------------
  if "%3" == "CGA" goto PARAM_OK
  if "%3" == "EGA" goto PARAM_OK

  rem   To display help information: runs rockinst.bat
  rem   -----------------------------------------------------------------------

  if exist %1ROCKINST.BAT %1rockinst.bat -?
  cls
  echo  Please insert Original Disk #1 in drive %1 and press any key when ready
  %1_getkey
  %1rockinst.bat -?
  echo  %1ROCKINST.BAT not found, should be on Original DIsk #1 !
  goto EOBATCH

:PARAM_OK

  rem   prepare destination disk #1
  rem   -----------------------------------------------------------------------
  %1_dskres

  cls
  echo  ÿ
  echo  Please insert your blank disk #1 in drive %2. if you are working with
  echo  one diskdrive, use this disk, whenever DOS prompts you for drive %2.
  echo  ÿ
  echo  Press any key when ready.
  %1_getkey

  rem   Copy common stuff from disk #1. In case any of these files isn't
  rem   present the user is prompted for this disk
  rem   -----------------------------------------------------------------------

:COPYPROG
  cls
  if exist %1ROCKROLL.EXE goto PROG_OK
  echo  Please insert Original Disk #1 in drive %1 and press any key when ready
  %1_getkey
  goto  COPYPROG

:PROG_OK
  %1_dskres
  echo  Installing %1Rock'n Roll - program & basic data to %2game disk #1 ...
  echo  ÿ
  %1_bigcopy %1 %2 ROCKROLL.DAT ROCKROLL.EXE
  if errorlevel 1 goto EOBATCH

  rem   prepare destination disk #2
  rem   -----------------------------------------------------------------------
  %1_dskres

  cls
  echo  ÿ
  echo  Please insert your blank disk #2 in drive %2. if you are working with
  echo  one diskdrive, use this disk, whenever DOS prompts you for drive %2.
  echo  ÿ
  echo  Press any key when ready.
  %1_getkey

  rem   We don't need the CGA-data for the EGA-installation
  rem   -----------------------------------------------------------------------

  if %3 == EGA goto NOCGA

:COPYCGA
  cls
  if exist %1RRCGA.DAT goto CGA_OK
  echo  Please insert Original Disk #1 in drive %1 and press any key when ready
  %1_getkey
  goto  COPYCGA

:CGA_OK
  %1_dskres
  echo  Installing %1Rock'n Roll - Hercules/CGA data to %2game disk #2 ...
  echo  ÿ
  %1_bigcopy %1 %2 RRCGA.DAT

:NOCGA

  rem   Copy the other data from disk #2. In case any of these files isn't
  rem   present the user is prompted for this disk. If all the sourcefiles
  rem   are on one disk, this batch won't prompt.
  rem   -----------------------------------------------------------------------

:COPYLEV
  %1_dskres
  cls
  if exist %1RRLEV.DAT goto LEV_OK
  echo  Please insert Original Disk #2 in drive %1 and press any key when ready
  %1_getkey
  goto  COPYLEV

:LEV_OK
  rem   We don't need the EGA-data for the CGA-installation
  rem   -----------------------------------------------------------------------

  if %3 == CGA goto NOEGA

  echo  Installing %1Rock'n Roll - level & EGA/VGA data to %2game disk #2 ...
  echo  ÿ
  %1_bigcopy %1 %2 RREGA.DAT RRLEV.DAT
  if errorlevel 1 goto EOBATCH
  goto DONE

:NOEGA
  echo  Installing %1Rock'n Roll - level data to %2game disk #2 ...
  echo  ÿ
  %1_bigcopy %1 %2 RRLEV.DAT
  if errorlevel 1 goto EOBATCH

:DONE

  rem   Installation done
  rem   -----------------------------------------------------------------------

  cls
  echo  ÿ
  echo  ÿ
  echo  To run ROCK'N ROLL, insert the game disk #1 into drive %2 and type
  echo  ÿ
  echo  %2 [Enter]
  echo  ROCKROLL [Enter]
  echo  ÿ
  goto  EOBATCH

:EOBATCH

