
echo off

  rem   ROCK'N ROLL Installation Batch Program, Copyright 1991 by Rainbow Arts
  rem   -----------------------------------------------------------------------
  rem   This batch allows easy installation of ROCK'N ROLL on IBM compatibles.
  rem   To get a help message simply type "ROCKINST" or "ROCKINST -?". You may
  rem   copy the game to floppy disk or hard disk selecting different versions
  rem   of the game (EGA, CGA, ...). The GETKEY utility _GK.COM is a Palladix
  rem   Public Domain program - feel free to use it for your own purposes.
  rem   All other batch files are called by this batch to do the real work.
  rem   -----------------------------------------------------------------------

  rem   Check for command line arguments, display help if anything is wrong
  rem   -----------------------------------------------------------------------
  if "%1" == "-?"   goto SHOWHELP
  if "%1" == "/?"   goto SHOWHELP
  if "%1" == ""     goto SHOWHELP
  if "%2" == ""     goto SHOWHELP

  rem   Check for additional batch files necessary to install
  rem   -----------------------------------------------------------------------
  if not exist %1_instl.bat goto BAT_MISSING
  if not exist %1_copy.bat goto BAT_MISSING
  if not exist %1_copy360.bat goto BAT_MISSING

  rem   Check wether the user knows what he does, just to be sure ...
  cls
  echo  ÿ
  echo  Security check ...
  echo  ÿ

  if "%3" == ""     goto CHKDISK

  echo  Please press [Enter] to confirm installation to HARD DISK: %2%3
  goto  CHKBOTH

:CHKDISK

  echo  Please press [Enter] to confirm installation to FLOPPY DISK %2

:CHKBOTH

  echo  or [Escape] to view the help message.
  %1_getkey (cr) (esc)
  if errorlevel 2 goto SHOWHELP

:V_SELECT

  rem   Clear screen, display copyright and title stuff
  rem   -----------------------------------------------------------------------
  cls
  echo ÿ
  echo  ROCK'N ROLL Installation, Copyright (C) 1989-1991 by Rainbow Arts
  echo  -----------------------------------------------------------------
  echo ÿ

  rem   Select video adapters
  rem   -----------------------------------------------------------------------
  echo  Please choose one of the following video adapters, default is [1]
  echo  ÿ
  echo  1. Support all video adapters
  echo  2. Hercules or CGA or small EGA
  echo  3. EGA or VGA
  echo  ÿ
  echo  Press [Esc] to abort installation
  echo  ÿ
  %1_getkey 1(cr) 2 3 4(esc)

  if errorlevel 5 goto SHOWHELP
  if errorlevel 4 goto V_EGAVGA
  if errorlevel 3 goto V_CGAMGA

  rem   Install all video adapters
  rem   -----------------------------------------------------------------------
  %1_instl %1 %2 ALL %3
  goto  BAT_MISSING

:V_EGAVGA

  rem   Installing EGA/VGA modes
  rem   -----------------------------------------------------------------------
  %1_instl %1 %2 EGA %3
  goto  BAT_MISSING

:V_CGAMGA

  rem   Installing Hercules/CGA modes
  rem   -----------------------------------------------------------------------
  %1_instl %1 %2 CGA %3
  goto  BAT_MISSING

:BAT_MISSING
  cls
  echo  ÿ
  echo  Installation aborted: batch file (_instl.bat, _copy.bat, or _copy360.bat )
  echo  missing on disk %1!
  echo  ÿ
  goto  EOBATCH

:SHOWHELP

  rem   Display help text and terminate batch
  rem   -----------------------------------------------------------------------
  cls
  echo  ÿ
  echo  Please try again with up to 3 command line arguments: The first argument  you
  echo  have  to supply is the source drive - that's the disk drive where you want to
  echo  install the game from (usually the A: disk drive).
  echo  ÿ
  echo  The second argument must contain the destination drive - that's the drive you
  echo  want to have all the files being copied to. If you  don't use a harddisk, the
  echo  second  argument  should  always  be drive B:, regardless wether you actually
  echo  have 2 disk drives present or not.
  echo  ÿ
  echo  The third argument is for hard disk users only and  specifies  the  directory
  echo  where you want the game to be located.
  echo  ÿ
  echo  Example 1 : Install ROCK'N ROLL on a PC with only one disk drive
  echo              ROCKINST A: B:
  echo  ÿ
  echo  Example 2 : Install ROCK'N ROLL on a PC with two disk drives
  echo              ROCKINST A: B:
  echo  ÿ
  echo  Example 3 : Install ROCK'N ROLL on harddisk
  echo              ROCKINST A: C: \ROCKROLL
  echo  ÿ
  echo  ***************** Please press any key to return to DOS ... *****************
  %1_getkey

:EOBATCH

