
echo off

  rem   ROCK'N ROLL Installation Batch Program, Copyright 1991 by Rainbow Arts
  rem   -----------------------------------------------------------------------
  rem   This batch is call by _INSTL.BAT to do the actual copying to one large
  rem   disk or harddisk. For installation on 360k-disks _copy360.bat is used.
  rem   Parameters used:
  rem   %1 - source-drive
  rem   %2 - destination-drive
  rem   %3 - what to install: EGA, CGA, ALL
  rem   %4 - destination path
  rem   -----------------------------------------------------------------------

  rem   Check command line arguments
  rem   -----------------------------------------------------------------------
  if "%3" == "CGA" goto PARAM_OK
  if "%3" == "EGA" goto PARAM_OK
  if "%3" == "ALL" goto PARAM_OK

  rem   To display help information: runs rockinst.bat
  rem   -----------------------------------------------------------------------

  if exist %1ROCKINST.BAT %1rockinst.bat -?
  cls
  echo  Please insert Original Disk #1 in drive %1 and press any key when ready
  %1_getkey
  %1rockinst.bat -?
  echo  %1ROCKINST.BAT not found, should be on Original DIsk #1 !
  goto EOBATCH

:PARAM_OK

  rem   prepare destination disk
  rem   -----------------------------------------------------------------------
  %1_dskres

  if NOT "%4" == "" goto HARDDISK
  cls
  echo  ÿ
  echo  Please insert your blank disk #1 in drive %2. if you are working with
  echo  one diskdrive, use this disk, whenever DOS prompts you for drive %2.
  echo  ÿ
  echo  Press any key when ready.
  %1_getkey

:HARDDISK

  rem   Copy common stuff from disk #1. In case any of these files isn't
  rem   present the user is prompted for this disk
  rem   -----------------------------------------------------------------------

:COPYPROG
  cls
  %1_dskres
  if exist %1ROCKROLL.EXE goto PROG_OK
  echo  Please insert Original Disk #1 in drive %1 and press any key when ready
  %1_getkey
  goto  COPYPROG

:PROG_OK

  rem   We don't need the CGA-data for the EGA-installation
  rem   -----------------------------------------------------------------------

  if %3 == EGA goto NOCGA

:CGA_OK
  echo  Installing %1Rock'n Roll - program, basic, Hercules/CGA data to %2%4 ...
  echo  ÿ
  %1_bigcopy %1 %2%4 ROCKROLL.DAT ROCKROLL.EXE RRCGA.DAT
  if errorlevel 1 goto EOBATCH

  goto DISK2

:NOCGA

  echo  Installing %1Rock'n Roll - program, basic, Hercules/CGA data to %2%4 ...
  echo  ÿ
  %1_bigcopy %1 %2%4 ROCKROLL.DAT ROCKROLL.EXE
  if errorlevel 1 goto EOBATCH


:DISK2
  rem   Copy the other data from disk #2. In case any of these files isn't
  rem   present the user is prompted for this disk. If all the sourcefiles
  rem   are on one disk, this batch won't prompt.
  rem   -----------------------------------------------------------------------

:COPYLEV
  cls
  if exist %1RRLEV.DAT goto LEV_OK
  %1_dskres
  echo  Please insert Original Disk #2 in drive %1 and press any key when ready
  %1_getkey
  goto  COPYLEV

:LEV_OK
  %1_dskres
  rem   We don't need the EGA-data for the CGA-installation
  rem   -----------------------------------------------------------------------

  if %3 == CGA goto NOEGA

  echo  Installing %1Rock'n Roll - level, EGA/VGA data to %2%4 ...
  echo  ÿ
  %1_bigcopy %1 %2%4 RREGA.DAT RRLEV.DAT
  if errorlevel 1 goto EOBATCH
  goto DONE

:NOEGA
  echo  Installing %1Rock'n Roll - level data to %2%4 ...
  echo  ÿ
  %1_bigcopy %1 %2%4 RRLEV.DAT
  if errorlevel 1 goto EOBATCH

:DONE
  rem   Installation done
  rem   -----------------------------------------------------------------------

  cls
  echo  ÿ
  echo  ÿ
  echo  To run ROCK'N ROLL, type
  echo  ÿ
  echo  %2 [Enter]

  rem   Don't show CD if destination was a floppy disk
  rem   -----------------------------------------------------------------------

  if "%4" == "" goto NODIRARG

  echo  cd %4 [Enter]

:NODIRARG

  echo  ROCKROLL [Enter]
  echo  ÿ
  goto  EOBATCH


:EOBATCH

