/* $Copyright:	$
 * Copyright (c) 1984, 1985, 1986, 1987, 1988, 1989, 1990 
 * Sequent Computer Systems, Inc.   All rights reserved.
 *  
 * This software is furnished under a license and may be used
 * only in accordance with the terms of that license and with the
 * inclusion of the above copyright notice.   This software may not
 * be provided or otherwise made available to, or used by, any
 * other person.  No title to or ownership of the software is
 * hereby transferred.
 */

/* Example loader command file to change the separation between 
 * the end of .bss and the beginning of .shdata to 0x100000 (1 megabyte).
 * The default is 0x80000 (512 K).
 *
 * Note: the value 0x100000 used in this file can be changed to specify
 * more or less space, but it must always be a multiple of 0x1000.
 */

SECTIONS 
{
	/* Leave enough room for headers before starting .text */
	.text 0x200 BLOCK(0x200) : { *(.init) *(.text) }
	
	/* .data and .bss are just like the default */
	GROUP BIND (NEXT(0x1000) + ((SIZEOF(.text) + ADDR(.text)) % 0x1000)) : 
	{
		.data	: { }
		.bss	: { }
	}

	/* All this just to say 0x100000 (1 MB) beyond the end .bss,
	 * then align to the next page.
	 */
	GROUP BIND
	    ( 0x100000  /* <-- Adjust this to change .bss to .shdata gap */

	      /* end of .bss */
	      + NEXT(0x1000) + ( ( SIZEOF(.text) + ADDR(.text) ) % 0x1000 )
	      + SIZEOF(.data) + SIZEOF(.bss) 

	      /* align to next page */
	      + 0x1000 
	      -  ( ( ( ( SIZEOF(.text) + ADDR(.text) ) % 0x1000 )
	               + SIZEOF(.data) + SIZEOF(.bss) ) % 0x1000 )
	    ) BLOCK (0x1000) : 
	{
		.shdata	: { }
		.shbss  : { }
	}

	/* Like the default */
	.comment BLOCK(0x1000) : { *(.comment) }
}

