[Next] [Previous] [Top] [Contents] [Index]

Python 1.5 Reference Manual

# Chapter 7: Compound statements

Compound statements contain (groups of) other statements; they affect or control the execution of those other statements in some way. In general, compound statements span multiple lines, although in simple incarnations a whole compound statement may be contained in one line.

The if, while and for statements implement traditional control flow constructs. try specifies exception handlers and/or cleanup code for a group of statements. Function and class definitions are also syntactically compound statements.

Compound statements consist of one or more 'clauses'. A clause consists of a header and a 'suite'. The clause headers of a particular compound statement are all at the same indentation level. Each clause header begins with a uniquely identifying keyword and ends with a colon. A suite is a group of statements controlled by a clause. A suite can be one or more semicolon-separated simple statements on the same line as the header, following the header's colon, or it can be one or more indented statements on subsequent lines. Only the latter form of suite can contain nested compound statements; the following is illegal, mostly because it wouldn't be clear to which if clause a following else clause would belong:

    if test1: if test2: print x

Also note that the semicolon binds tighter than the colon in this context, so that in the following example, either all or none of the print statements are executed:

    if x < y < z: print x; print y; print z

Summarizing:

    compound_stmt:  if_stmt | while_stmt | for_stmt
                  | try_stmt | funcdef | classdef
    suite:          stmt_list NEWLINE | NEWLINE INDENT statement+ DEDENT
    statement:      stmt_list NEWLINE | compound_stmt
    stmt_list:      simple_stmt (";" simple_stmt)* [";"]

Note that statements always end in a NEWLINE possibly followed by a DEDENT. Also note that optional continuation clauses always begin with a keyword that cannot start a statement, thus there are no ambiguities (the 'dangling else' problem is solved in Python by requiring nested if statements to be indented).

The formatting of the grammar rules in the following sections places each clause on a separate line for clarity.

## 7.1 The if statement

The if statement is used for conditional execution:

    if_stmt:        "if" expression ":" suite
                   ("elif" expression ":" suite)*
                   ["else" ":" suite]

It selects exactly one of the suites by evaluating the expressions one by one until one is found to be true (see section "Boolean operations" on page 35 for the definition of true and false); then that suite is executed (and no other part of the if statement is executed or evaluated). If all expressions are false, the suite of the else clause, if present, is executed.

## 7.2 The `while` statement

The while statement is used for repeated execution as long as an expression is true:

    while_stmt:     "while" expression ":" suite
                   ["else" ":" suite]

This repeatedly tests the expression and, if it is true, executes the first suite; if the expression is false (which may be the first time it is tested) the suite of the else clause, if present, is executed and the loop terminates.

A break statement executed in the first suite terminates the loop without executing the else clause's suite. A continue statement executed in the first suite skips the rest of the suite and goes back to testing the expression.

## 7.3 The `for` statement

The for statement is used to iterate over the elements of a sequence (string, tuple or list):

    for_stmt:       "for" target_list "in" expression_list ":" suite
                   ["else" ":" suite]

The expression list is evaluated once; it should yield a sequence. The suite is then executed once for each item in the sequence, in the order of ascending indices. Each item in turn is assigned to the target list using the standard rules for assignments, and then the suite is executed. When the items are exhausted (which is immediately when the sequence is empty), the suite in the else clause, if present, is executed, and the loop terminates.

A break statement executed in the first suite terminates the loop without executing the else clause's suite. A continue statement executed in the first suite skips the rest of the suite and continues with the next item, or with the else clause if there was no next item.

The suite may assign to the variable(s) in the target list; this does not affect the next item assigned to it.

The target list is not deleted when the loop is finished, but if the sequence is empty, it will not have been assigned to at all by the loop. Hint: the built-in function range() returns a sequence of integers suitable to emulate the effect of Pascal's for i := a to b do; e.g. range(3) returns the list [0, 1, 2].

Warning: There is a subtlety when the sequence is being modified by the loop (this can only occur for mutable sequences, i.e. lists). An internal counter is used to keep track of which item is used next, and this is incremented on each iteration. When this counter has reached the length of the sequence the loop terminates. This means that if the suite deletes the current (or a previous) item from the sequence, the next item will be skipped (since it gets the index of the current item which has already been treated). Likewise, if the suite inserts an item in the sequence before the current item, the current item will be treated again the next time through the loop. This can lead to nasty bugs that can be avoided by making a temporary copy using a slice of the whole sequence, e.g.

    for x in a[:]:
        if x < 0: a.remove(x)

## 7.4 The `try` statement

The try statement specifies exception handlers and/or cleanup code for a group of statements:

    try_stmt:       try_exc_stmt | try_fin_stmt
    try_exc_stmt:   "try" ":" suite
                   ("except" [expression ["," target]] ":" suite)+
                   ["else" ":" suite]
    try_fin_stmt:   "try" ":" suite
                   "finally" ":" suite

There are two forms of try statement: try...except and try...finally. These forms cannot be mixed (but they can be nested in each other).

The try...except form specifies one or more exception handlers (the except clauses). When no exception occurs in the try clause, no exception handler is executed. When an exception occurs in the try suite, a search for an exception handler is started. This inspects the except clauses in turn until one is found that matches the exception. An expression-less except clause, if present, must be last; it matches any exception. For an except clause with an expression, that expression is evaluated, and the clause matches the exception if the resulting object is "compatible" with the exception. An object is compatible with an exception if it is either the object that identifies the exception, or (for exceptions that are classes) it is a base class of the exception, or it is a tuple containing an item that is compatible with the exception. Note that the object identities must match, i.e. it must be the same object, not just an object with the same value.

If no except clause matches the exception, the search for an exception handler continues in the surrounding code and on the invocation stack.

If the evaluation of an expression in the header of an except clause raises an exception, the original search for a handler is cancelled and a search starts for the new exception in the surrounding code and on the call stack (it is treated as if the entire try statement raised the exception).

When a matching except clause is found, the exception's parameter is assigned to the target specified in that except clause, if present, and the except clause's suite is executed. When the end of this suite is reached, execution continues normally after the entire try statement. (This means that if two nested handlers exist for the same exception, and the exception occurs in the try clause of the inner handler, the outer handler will not handle the exception.)

Before an except clause's suite is executed, details about the exception are assigned to three variables in the sys module: sys.exc_type receives the object identifying the exception; sys.exc_value receives the exception's parameter; sys.exc_traceback receives a traceback object (see page 17) identifying the point in the program where the exception occurred. These details are also available through the `sys.exc_info()` function, which returns a tuple `(exc_type, exc_value, exc_traceback)`. Use of the corresponding variables is deprecated in favor of this function, since their use is unsafe in a threaded program. (As of Python 1.5, the variables are restored to their old values when returning from a function that handled an exception.)

The optional else clause is executed when no exception occurs in the try clause. Exceptions in the else clause are not handled by the preceding except clauses.

The try...finally form specifies a 'cleanup' handler. The try clause is executed. When no exception occurs, the finally clause is executed. When an exception occurs in the try clause, the exception is temporarily saved, the finally clause is executed, and then the saved exception is re-raised. If the finally clause raises another exception or executes a return, break or continue statement, the saved exception is lost. The exception information is not available to the program during execution of the finally clause.

When a return or break statement is executed in the try suite of a try...finally statement, the finally clause is also executed 'on the way out'. A continue statement is illegal in the try clause. (The reason is a problem with the current implementation -- this restriction may be lifted in the future).

## 7.5 Function definitions

A function definition defines a user-defined function object (see "The standard type hierarchy" on page 12):

    funcdef:        "def" funcname "(" [parameter_list] ")" ":" suite
    parameter_list: (defparameter ",")* ("*" identifier [, "**" identifier]
                                        | "**" identifier
                                        | defparameter [","])
    defparameter:   parameter ["=" expression]
    sublist:        parameter ("," parameter)* [","]
    parameter:      identifier | "(" sublist ")"
    funcname:       identifier

A function definition is an executable statement. Its execution binds the function name in the current local name space to a function object (a wrapper around the executable code for the function). This function object contains a reference to the current global name space as the global name space to be used when the function is called.

The function definition does not execute the function body; this gets executed only when the function is called.

When one or more top-level parameters have the form parameter = expression, the function is said to have "default parameter values". Default parameter values are evaluated when the function definition is executed. For a parameter with a default value, the correponding argument may be omitted from a call, in which case the parameter's default value is substituted. If a parameter has a default value, all following parameters must also have a default value -- this is a syntactic restriction that is not expressed by the grammar.[6]

Function call semantics are described in more detail in section "Calls" on page 31. A function call always assigns values to all parameters mentioned in the parameter list, either from position arguments, from keyword arguments, or from default values. If the form "*identifier" is present, it is initialized to a tuple receiving any excess positional parameters, defaulting to the empty tuple. If the form "**identifier" is present, it is initialized to a new dictionary receiving anyt excess keyword arguments, defaulting to a new empty dictionary.

It is also possible to create anonymous functions (functions not initially bound to a name), for immediate use in expressions. This uses lambda forms, described in section "Boolean operations" on page 35. Note that the lambda form is merely a shorthand for a simplified function definition; a function defined in a "def" statement can be passed around or assigned to another name just like a function defined by a lambda form. The "def" form is actually more powerful since it allows the execution of multiple statements.

Programmer's note: A "def" form executed inside a function definition defines a local function that can be returned or passed around. Because of Python's two-scope philosophy, a local function defined in this way does not have access to the local variables of the function that contains its definition; the same rule applies to functions defined by a lambda form. A standard trick to pass selected local variables into a locally defined function is to use default argument values, like this:

    # Return a function that returns its argument incremented by 'n'
    def make_incrementer(n):
        def increment(x, n=n):
            return x+n
        return increment

    add1 = make_incrementer(1)
    print add1(3)  # This prints '4'

## 7.6 Class definitions

A class definition defines a class object (see section "The standard type hierarchy" on page 12):

    classdef:       "class" classname [inheritance] ":" suite
    inheritance:    "(" [expression_list] ")"
    classname:      identifier

A class definition is an executable statement. It first evaluates the inheritance list, if present. Each item in the inheritance list should evaluate to a class object. The class's suite is then executed in a new execution frame (see section "Code blocks, execution frames, and name spaces" on page 23), using a newly created local name space and the original global name space. (Usually, the suite contains only function definitions.) When the class's suite finishes execution, its execution frame is discarded but its local name space is saved. A class object is then created using the inheritance list for the base classes and the saved local name space for the attribute dictionary. The class name is bound to this class object in the original local name space.

Programmer's note: variables defined in the class definition are class variables; they are shared by all instances. To define instance variables, they must be given a value in the the `__init__` method or in another method. Both class and instance variables are accessible through the notation "`self.name`", and an instance variable hides a class variable with the same name when accessed in this way. Class variables with immutable values can be used as defaults for instance variables.

[6] Currently this is not checked; instead, def f(a=1,b) is interpreted as def f(a=1,b=None).

7.1 - The if statement
7.2 - The while statement
7.3 - The for statement
7.4 - The try statement
7.5 - Function definitions
7.6 - Class definitions

[Next] [Previous] [Top] [Contents] [Index]

Generated with Harlequin WebMaker