[Next] [Previous] [Top] [Contents] [Index]

Python 1.5 Reference Manual

# Chapter 5: Expressions

This chapter explains the meaning of the elements of expressions in Python.

Syntax notes: in this and the following chapters, extended BNF notation will be used to describe syntax, not lexical analysis. When (one alternative of) a syntax rule has the form

    name:    othername

and no semantics are given, the semantics of this form of `name` are the same as for `othername`.

## 5.1 Arithmetic conversions

When a description of an arithmetic operator below uses the phrase "the numeric arguments are converted to a common type", the arguments are coerced using the coercion rules listed at the end of chapter 3. If both arguments are standard numeric types, the following coercions are applied:

- If either argument is a complex number, the other is converted to complex;

- otherwise, if either argument is a floating point number, the other is converted to floating point;

- otherwise, if either argument is a long integer, the other is converted to long integer;

- otherwise, both must be plain integers and no conversion is necessary.

Some additional rules apply for certain operators (e.g. a string left argument to the '`%`' operator). Extensions can define their own coercions.

## 5.2 Atoms

Atoms are the most basic elements of expressions. The simplest atoms are identifiers or literals. Forms enclosed in reverse quotes or in parentheses, brackets or braces are also categorized syntactically as atoms. The syntax for atoms is:

    atom:      identifier | literal | enclosure
    enclosure: parenth_form|list_display|dict_display|string_conversion

### 5.2.1 Identifiers (Names)

An identifier occurring as an atom is a reference to a local, global or built-in name binding. If a name is assigned to anywhere in a code block (even in unreachable code), and is not mentioned in a `global` statement in that code block, then it refers to a local name throughout that code block. When it is not assigned to anywhere in the block, or when it is assigned to but also explicitly listed in a `global` statement, it refers to a global name if one exists, else to a built-in name (and this binding may dynamically change).

When the name is bound to an object, evaluation of the atom yields that object. When a name is not bound, an attempt to evaluate it raises a `NameError` exception.

Private name mangling: when an identifier that textually occurs in a class definition begins with two or more underscore characters and does not end in two or more underscores, it is considered a "private name" of that class. Private names are transformed to a longer form before code is generated for them. The transformation inserts the class name in front of the name, with leading underscores removed, and a single underscore inserted in front of the class name. For example, the identifier __spam occurring in a class named Ham will be transformed to _Ham__spam. This transformation is independent of the syntactical context in which the identifier is used. If the transformed name is extremely long (longer than 255 characters), implementation defined truncation may happen. If the class name consists only of underscores, no transformation is done.

### 5.2.2 Literals

Python supports string literals and various numeric literals:

    literal:   stringliteral | integer | longinteger | floatnumber | imagnumber

Evaluation of a literal yields an object of the given type (string, integer, long integer, floating point number, complex number) with the given value. The value may be approximated in the case of floating point and imaginary (complex) literals. (See "Literals" on page 6 for details.)

All literals correspond to immutable data types, and hence the object's identity is less important than its value. Multiple evaluations of literals with the same value (either the same occurrence in the program text or a different occurrence) may obtain the same object or a different object with the same value.

### 5.2.3 Parenthesized forms

A parenthesized form is an optional expression list enclosed in parentheses:

    parenth_form:      "(" [expression_list] ")"

A parenthesized expression list yields whatever that expression list yields: if the list contains at least one comma, it yields a tuple; otherwise, it yields the single expression that makes up the expression list.

An empty pair of parentheses yields an empty tuple object. Since tuples are immutable, the rules for literals apply(i.e., two occurrences of the empty tuple may or may not yield the same object).

Note that tuples are not formed by the parentheses, but rather by use of the comma operator. The exception is the empty tuple, for which parentheses are required -- allowing unparenthesized "nothing" in expressions would cause ambiguities and allow common typos to pass uncaught.

### 5.2.4 List displays

A list display is a possibly empty series of expressions enclosed in square brackets:

    list_display:   "[" [expression_list] "]"

A list display yields a new list object. If it has no expression list, the list object has no items. Otherwise, the elements of the expression list are evaluated from left to right and inserted in the list object in that order.

### 5.2.5 Dictionary displays

A dictionary display is a possibly empty series of key/datum pairs enclosed in curly braces:

    dict_display:   "{" [key_datum_list] "}"
    key_datum_list: key_datum ("," key_datum)* [","]
    key_datum:      expression ":" expression

A dictionary display yields a new dictionary object

The key/datum pairs are evaluated from left to right to define the entries of the dictionary: each key object is used as a key into the dictionary to store the corresponding datum.

Restrictions on the types of the key values are listed earlier in "The standard type hierarchy" on page 12 (to summarize, the key type should be hashable, which excludes all mutable objects). Clashes between duplicate keys are not detected; the last datum (textually rightmost in the display) stored for a given key value prevails.

### 5.2.6 String conversions

A string conversion is an expression list enclosed in reverse (a.k.a. backward) quotes:

    string_conversion: "'" expression_list "'"

A string conversion evaluates the contained expression list and converts the resulting object into a string according to rules specific to its type.

If the object is a string, a number, `None`, or a tuple, list or dictionary containing only objects whose type is one of these, the resulting string is a valid Python expression which can be passed to the built-in function `eval()` to yield an expression with the same value (or an approximation, if floating point numbers are involved).

(In particular, converting a string adds quotes around it and converts "funny" characters to escape sequences that are safe to print.)

It is illegal to attempt to convert recursive objects (e.g. lists or dictionaries that contain a reference to themselves, directly or indirectly.)

The built-in function `repr()` performs exactly the same conversion in its argument as enclosing it in parentheses and reverse quotes does. The built-in function `str()` performs a similar but more user-friendly conversion.

## 5.3 Primaries

Primaries represent the most tightly bound operations of the language. Their syntax is:

    primary:        atom | attributeref | subscription | slicing | call

### 5.3.1 Attribute references

An attribute reference is a primary followed by a period and a name:

    attributeref:   primary "." identifier

The primary must evaluate to an object of a type that supports attribute references. This object is then asked to produce the attribute whose name is the identifier. If this attribute is not available, the exception `AttributeError` is raised. Otherwise, the type and value of the object produced is determined by the object. Multiple evaluations of the same attribute reference may yield different objects.

### 5.3.2 Subscriptions

A subscription selects an item of a sequence (string, tuple or list) or mapping (dictionary) object:

    subscription:   primary "[" expression_list "]"

The primary must evaluate to an object of a sequence or mapping type.

If the primary is a mapping, the expression list must evaluate to an object whose value is one of the keys of the mapping, and the subscription selects the value in the mapping that corresponds to that key.

If the primary is a sequence, the expression (list) must evaluate to a plain integer. If this value is negative, the length of the sequence is added to it (so that, e.g. `x[-1]` selects the last item of `x`.) The resulting value must be a nonnegative integer less than the number of items in the sequence, and the subscription selects the item whose index is that value (counting from zero).

A string's items are characters. A character is not a separate data type but a string of exactly one character.

### 5.3.3 Slicings

A slicing selects a range of items in a sequence (string, tuple or list) object. Slicings may be used as expressions or as targets in assignment or `del` statements. The syntax for a slicing:

    slicing:          simple_slicing | extended_slicing
    simple_slicing:   primary "[" short_slice "]"
    extended_slicing: primary "[" slice_list "]"
    slice_list:       slice_item ("," slice_item)* [","]
    slice_item:       expression | proper_slice | ellipsis
    proper_slice:     short_slice | long_slice
    short_slice:      [lower_bound] ":" [upper_bound]
    long_slice:       short_slice ":" [stride]
    lower_bound:      expression
    upper_bound:      expression
    stride:           expression
    ellipsis:         "..."

There's an ambiguity in the formal syntax here: anything that looks like an expression list also looks like a slice list, so any subscription can be interpreted as a slicing. Rather than further complicating the syntax, this is disambiguated by declaring that in this case the interpretation as a subscription takes priority over the interpretation as a slicing (this is the case if the slice list contains no proper slice nor ellipses). Similarly, when the slice list has exactly one short slice and no trailing comma, the interpretation as a simple slicing takes priority over that as an extended slicing.

The semantics for a simple slicing are as follows. The primary must evaluate to a sequence object. The lower and upper bound expressions, if present, must evaluate to plain integers; defaults are zero and the sequence's length, respectively. If either bound is negative, the sequence's length is added to it. The slicing now selects all items with index k such that i <= k < j where i and j are the specified lower and upper bounds. This may be an empty sequence. It is not an error if i or j lie outside the range of valid indexes (such items don't exist so they aren't selected).

The semantics for an extended slicing are as follows. The primary must evaluate to a mapping object, and it is indexed with a key that is constructed from the slice list, as follows. If the slice list contains at least one comma, the key is a tuple containing the conversion of the slice items; otherwise, the conversion of the lone slice item is the key. The conversion of a slice item that is an expression is that expression. The conversion of an ellipsis slice item is the built-in `Ellipsis` object. The conversion of a proper slice is a slice object (see page 17) whose `start`, `stop` and `step` attributes are the values of the expressions given as lower bound, upper bound and stride, respectively, substituting `None` for missing expressions.

### 5.3.4 Calls

A call calls a callable object (e.g. a function) with a possibly empty series of arguments:

    call:                 primary "(" [argument_list [","]] ")"
    argument_list:        positional_arguments ["," keyword_arguments]
                        | keyword_arguments
    positional_arguments: expression ("," expression)*
    keyword_arguments:    keyword_item ("," keyword_item)*
    keyword_item:         identifier "=" expression

A trailing comma may be present after an argument list but does not affect the semantics.

The primary must evaluate to a callable object (user-defined functions, built-in functions, methods of built-in objects, class objects, methods of class instances, and certain class instances themselves are callable; extensions may define additional callable object types). All argument expressions are evaluated before the call is attempted. Please refer to "Function definitions" on page 50 for the syntax of formal parameter lists.

If keyword arguments are present, they are first converted to positional arguments, as follows. First, a list of unfilled slots is created for the formal parameters. If there are N positional arguments, they are placed in the first N slots. Next, for each keyword argument, the identifier is used to determine the corresponding slot (if the identifier is the same as the first formal parameter name, the first slot is used, and so on). If the slot is already filled, a `TypeError` exception is raised. Otherwise, the value of the argument is placed in the slot, filling it (even if the expression is `None`, it fills the slot). When all arguments have been processed, the slots that are still unfilled are filled with the corresponding default value from the function definition. (Default values are calculated, once, when the function is defined; thus, a mutable object such as a list or dictionary used as default value will be shared by all calls that don't specify an argument value for the corresponding slot; this should usually be avoided.) If there are any unfilled slots for which no default value is specified, a `TypeError` exception is raised. Otherwise, the list of filled slots is used as the argument list for the call.

If there are more positional arguments than there are formal parameter slots, a `TypeError` exception is raised, unless a formal parameter using the syntax''`*identifier`'' is present; in this case, that formal parameter receives a tuple containing the excess positional arguments (or an empty tuple if there were no excess positional arguments).

If any keyword argument does not correspond to a formal parameter name, a `TypeError` exception is raised, unless a formal parameter using the syntax ''`**identifier`'' is present; in this case, that formal parameter receives a dictionary containing the excess keyword arguments (using the keywords as keys and the argument values as corresponding values), or a (new) empty dictionary if there were no excess keyword arguments.

Formal parameters using the syntax ''`*identifier`'' or ''`**identifier`'' cannot be used as positional argument slots or as keyword argument names. Formal parameters using the syntax ''`(sublist)`'' cannot be used as keyword argument names; the outermost sublist corresponds to a single unnamed argument slot, and the argument value is assigned to the sublist using the usual tuple assignment rules after all other parameter processing is done.

A call always returns some value, possibly `None`, unless it raises an exception. How this value is computed depends on the type of the callable object.

If it is:

a user-defined function: the code block for the function is executed, passing it the argument list. The first thing the code block will do is bind the formal parameters to the arguments; this is described in section"Function definitions" on page 50. When the code block executes a `return` statement, this specifies the return value of the function call.

a built-in function or method: the result is up to the interpreter; see the library reference manual for the descriptions of built-in functions and methods.

a class object: a new instance of that class is returned.

a class instance method: the corresponding user-defined function is called, with an argument list that is one longer than the argument list of the call. The instance becomes the first argument.

## 5.4 The power operator

The power operator binds more tightly than unary operators on its left; it binds less tightly than unary operators on its right. The syntax is:

    power:         primary ["**" u_expr]

Thus, in an unparenthesized sequence of power and unary operators, the operators are evaluated from right to left (this does not constrain the evaluation order for the operands).

The power operator has the same semantics as the built-in `pow()` function: it yields its left argument raised to the power of its right argument. The numeric arguments are first converted to a common type. The result type is that of the arguments after coercion; if the result is not expressible in that type (as in raising an integer to a negative power, or a negative floating point number to a broken power), a `TypeError` exception is raised.

## 5.5 Unary arithmetic operations

All unary arithmetic (and bit-wise) operations have the same priority:

    u_expr:         power | "-" u_expr | "+" u_expr | "~" u_expr

The unary `"-"` (minus) operator yields the negation of its numeric argument.

The unary `"+"` (plus) operator yields its numeric argument unchanged.

The unary `"~"` (invert) operator yields the bit-wise inversion of its plain or long integer argument. The bit-wise inversion of `x` is defined as `-(x+1)`. It only applies to integral numbers.

In all three cases, if the argument does not have the proper type, a `TypeError` exception is raised.

## 5.6 Binary arithmetic operations

The remaining binary arithmetic operations have the conventional priority levels. Note that some of these operations also apply to certain non-numeric types. Apart from the power operator, there are only two levels, one for multiplicative operators and one for additive operators:

    m_expr:         u_expr | m_expr "*" u_expr
                  | m_expr "/" u_expr | m_expr "%" u_expr
    a_expr:         m_expr | aexpr "+" m_expr | aexpr "-" m_expr

The "`*`" (multiplication) operator yields the product of its arguments. The arguments must either both be numbers, or one argument must be a plain integer and the other must be a sequence. In the former case, the numbers are converted to a common type and then multiplied together. In the latter case, sequence repetition is performed; a negative repetition factor yields an empty sequence.

The "`/`" (division) operator yields the quotient of its arguments. The numeric arguments are first converted to a common type. Plain or long integer division yields an integer of the same type; the result is that of mathematical division with the 'floor' function applied to the result. Division by zero raises the `ZeroDivisionError` exception

The "`%`" (modulo) operator yields the remainder from the division of the first argument by the second. The numeric arguments are first converted to a common type. A zero right argument raises the `ZeroDivisionError` exception. The arguments may be floating point numbers, e.g. `3.14%0.7` equals `0.34` (since `3.14` equals `4*0.7+0.34`). The modulo operator always yields a result with the same sign as its second operand (or zero); the absolute value of the result is strictly smaller than the second operand.

The integer division and modulo operators are connected by the following identity: `x == (x/y)*y + (x%y)`. Integer division and modulo are also connected with the built-in function `divmod()`: `divmod(x, y) == (x/y, x%y)`. These identities don't hold for floating point and complex numbers; there a similar identity holds where `x/y` is replaced by `floor(x/y)`) or
`floor((x/y).real)`, respectively.

The `"+"` (addition) operator yields the sum of its arguments. The arguments must either both be numbers, or both sequences of the same type. In the former case, the numbers are converted to a common type and then added together. In the latter case, the sequences are concatenated.

The `"-"` (subtraction) operator yields the difference of its arguments. The numeric arguments are first converted to a common type.

## 5.7 Shifting operations

The shifting operations have lower priority than the arithmetic operations:

    shift_expr:     a_expr | shift_expr ( "<<" | ">>" ) a_expr

These operators accept plain or long integers as arguments. The arguments are converted to a common type. They shift the first argument to the left or right by the number of bits given by the second argument.

A right shift by n bits is defined as division by `pow(2,`n). A left shift by n bits is defined as multiplication with `pow(2,`n); for plain integers there is no overflow check so this drops bits and flips the sign if the result is not less than `pow(2,31)` in absolute value. Negative shift counts raise a `ValueError` exception.

## 5.8 Binary bit-wise operations

Each of the three bitwise operations has a different priority level:

    and_expr:       shift_expr | and_expr "&" shift_expr
    xor_expr:       and_expr | xor_expr "^" and_expr
    or_expr:       xor_expr | or_expr "|" xor_expr

The `"&"` operator yields the bit-wise AND of its arguments, which must be plain or long integers. The arguments are converted to a common type.

The `"^"` operator yields the bitwise XOR (exclusive OR) of its arguments, which must be plain or long integers. The arguments are converted to a common type.

The `"|"` operator yields the bitwise (inclusive) OR of its arguments, which must be plain or long integers. The arguments are converted to a common type.

## 5.9 Comparisons

Contrary to C, all comparison operations in Python have the same priority, which is lower than that of any arithmetic, shifting or bitwise operation. Also contrary to C, expressions like `a < b < c` have the interpretation that is conventional in mathematics:

    comparison:     or_expr (comp_operator or_expr)*
    comp_operator:  "<"|">"|"=="|">="|"<="|"<>"|"!="|"is" ["not"]|["not"] "in"

Comparisons yield integer values: 1 for true, 0 for false.

Comparisons can be chained arbitrarily, e.g. `x < y <= z` is equivalent to `x < y and y <= z,` except that `y` is evaluated only once (but in both cases `z` is not evaluated at all when `x < y` is found to be false).

Formally, if a, b, c, ..., y, z are expressions and opa, opb, ..., opy are comparison operators, then a opa b opb c ... y opy z is equivalent to a opa b `and b opb c` `and` ... y opy z, except that each expression is evaluated at most once.

Note that a opa b opb c doesn't imply any kind of comparison between a and c, so that e.g. `x < y > z` is perfectly legal (though perhaps not pretty).

The forms `<>` and `!=` are equivalent; for consistency with C, `!=` is preferred; where `!=` is mentioned below `<>` is also implied.

The operators `"<", ">", "==", ">=", "<="`, and `"!="` compare the values of two objects. The objects needn't have the same type. If both are numbers, they are converted to a common type. Otherwise, objects of different types always compare unequal, and are ordered consistently but arbitrarily. (This unusual definition of comparison is done to simplify the definition of operations like sorting and the `in` and `not` `in` operators.)

Comparison of objects of the same type depends on the type:

- Numbers are compared arithmetically.

- Strings are compared lexicographically using the numeric equivalents (the result of the built-in function `ord`) of their characters.

- Tuples and lists are compared lexicographically using comparison of corresponding items.

- Mappings (dictionaries) are compared through lexicographic comparison of their sorted (key, value) lists.[3]

- Most other types compare unequal unless they are the same object; the choice whether one object is considered smaller or larger than another one is made arbitrarily but consistently within one execution of a program.

The operators `in` and `not in` test for sequence membership: if y is a sequence, x in y is true if and only if there exists an index i such that x = y[i]. x not in y yields the inverse truth value. The exception `TypeError` is raised when y is not a sequence, or when y is a string and x is not a string of length one.[4]

The operators `is` and `is not` test for object identity: x `is` y is true if and only if x and y are the same object. x `is not` y yields the inverse truth value.

## 5.10 Boolean operations

Boolean operations have the lowest priority of all Python operations:

    expression:      or_test | lambda_form
    or_test:        and_test | or_test "or" and_test
    and_test:       not_test | and_test "and" not_test
    not_test:       comparison | "not" not_test
    lambda_form:	"lambda" [parameter_list]: expression

In the context of Boolean operations, and also when expressions are used by control flow statements, the following values are interpreted as false: `None`, numeric zero of all types, empty sequences (strings, tuples and lists), and empty mappings (dictionaries). All other values are interpreted as true.

The operator `not` yields 1 if its argument is false, 0 otherwise.

The expression x `and` y first evaluates x; if x is false, its value is returned; otherwise, y is evaluated and the resulting value is returned.

The expression x `or` y first evaluates x; if x is true, its value is returned; otherwise, y is evaluated and the resulting value is returned.

(Note that neither `and` nor `or` restrict the value and type they return to 0 and 1, but rather return the last evaluated argument. This is sometimes useful, e.g. if `s` is a string that should be replaced by a default value if it is empty, the expression `s or 'foo'` yields the desired value. Because `not` has to invent a value anyway, it does not bother to return a value of the same type as its argument, so e.g. `not 'foo'` yields `0`, not `''`.)

Lambda forms (lambda expressions) have the same syntactic position as expressions. They are a shorthand to create anonymous functions; the expression `lambda` arguments`:` expression yields a function object that behaves virtually identical to one defined with

    def name (arguments):
        return expression

See "Function definitions" on page 50 for the syntax of parameter lists. Note that functions created with lambda forms cannot contain statements.

## 5.11 Expression lists

    expression_list:      expression ("," expression)* [","]

An expression list containing at least one comma yields a tuple. The length of the tuple is the number of expressions in the list. The expressions are evaluated from left to right.

The trailing comma is required only to create a single tuple (a.k.a. a single); it is optional in all other cases. A single expression without a trailing comma doesn't create a tuple, but rather yields the value of that expression. (To create an empty tuple, use an empty pair of parentheses: `()`.)

## 5.12 Summary

The following table summarizes the operator precedences in Python, from lowest precedence (least binding) to highest precedence (most binding). Operators in the same box have the same precedence. Unless the syntax is explicitly given, operators are binary. Operators in the same box group left to right (except for comparisons, which chain from left to right -- see above).

Operator Precedence
`or` | Boolean OR
`and` | Boolean AND
`not x` | Boolean NOT
`in, not in is, is not <, <=, >, >=, <>, !=, =` | Membership tests Identity tests Comparisons
`|` | Bitwise OR
`^` | Bitwise XOR
`&` | Bitwise AND
`<<, >>` | Shifts
`+, -` | Addition and subtraction
`*, /, %` | Multiplication, division, remainder
+x, -x ~x | Positive, negative Bitwise not
x.attribute x[index] x[index:index] f(arguments, ...) | Attribute reference Subscription Slicing Function call
(expressions . . .) [expressions . . .] {key:datum, . . .} `expression` | Binding or tuple display List display Dictionary display String conversion

[3] This is expensive since it requires sorting the keys first, but about the only sensible definition. An earlier version of Python compared dictionaries by identity only, but this caused surprises because people expected to be able to test a dictionary for emptiness by comparing it to `{}`.

[4] The latter restriction is sometimes a nuisance.

5.1 - Arithmetic conversions
5.2 - Atoms
5.2.1 - Identifiers (Names)
5.2.2 - Literals
5.2.3 - Parenthesized forms
5.2.4 - List displays
5.2.5 - Dictionary displays
5.2.6 - String conversions
5.3 - Primaries
5.3.1 - Attribute references
5.3.2 - Subscriptions
5.3.3 - Slicings
5.3.4 - Calls
5.4 - The power operator
5.5 - Unary arithmetic operations
5.6 - Binary arithmetic operations
5.7 - Shifting operations
5.8 - Binary bit-wise operations
5.9 - Comparisons
5.10 - Boolean operations
5.11 - Expression lists
5.12 - Summary

[Next] [Previous] [Top] [Contents] [Index]

Generated with Harlequin WebMaker