@echo off

if "%OS%"=="Windows_NT" goto NT
goto DOS

:NT

if "%PROCESSOR_ARCHITECTURE%" == "ALPHA" goto NT_ALPHA
if "%PROCESSOR_ARCHITECTURE%" == "MIPS" goto NT_MIPS
if "%PROCESSOR_ARCHITECTURE%" == "x86" goto NT_X86

echo.
echo Unable to determine operating system or processor architecture.
echo.
echo Consult your network administrator.
echo.
pause
goto DONE


:NT_ALPHA
cd alpha.bin
goto NT_RUN


:NT_MIPS
cd mips.bin
goto NT_RUN


:NT_X86
cd x86.bin
goto NT_RUN


:NT_RUN
echo.
echo This batch file will cause all SMS client software to be deinstalled 
echo from this machine.  The deinstall process will require 2 phases to 
echo complete.  
echo.
echo About to run phase 1.
echo.
pause
echo Running CLI_NT /R
cli_nt /r
echo.
echo Phase 1 of Client de-install complete.  You must now restart Windows NT
echo for the deinstallation to complete.
goto DONE

:DOS
cd x86.bin
echo.
echo This batch file will cause all SMS client software to be deinstalled 
echo from the client machine.  If Windows is installed on this machine, 
echo the deinstall process will require 2 phases to complete. Otherwise, 
echo the complete deinstallation will be done now.
echo.
echo About to run phase 1.
echo.
pause
echo Running CLI_DOS /R 
cli_dos /r
echo Phase 1 of Client de-install complete.  If this is a Windows machine, you 
echo must start or restart Windows now for the deinstallation to complete.
goto DONE


:DONE
echo.
pause